Макрос ЕАИСТО - открытый исходный код

Макрос ЕАИСТО - открытый исходный код

Макрос ЕАИСТО

Привет Эксперт, ниже я вставлю bat скрипт который сократит ожидание ответа сервера ГИС ГМП до 3х минут, пользоваться очень просто:

  1. Можно скачать, можно скопировать код в bat файл
  2. Установить Cromium-GOST
  3. перед созданием ДК запустить макрос из любого места, главное не закрывай cmd консоль, иначе она не удалит профиль
  4. как закончишь рёгать карту, нажал подписать, получил ДК, закрой браузер и консоль с макросом закроется
  5. как новая тачка приехала снова запусти макрос и так по кругу, запустил - зарёгал - закрыл открыл
Скачать 
@echo off
chcp 65001 >nul
setlocal EnableExtensions EnableDelayedExpansion

title автор Петров Андрей Алексеевич t.me/katomaigen
echo макрос работает

if "%~1"=="" (set "URL=https://eaisto.gibdd.ru/") else (set "URL=%~1")

set "BROWSER="
if defined CHROMIUM_GOST if exist "!CHROMIUM_GOST!" set "BROWSER=!CHROMIUM_GOST!"

if not defined BROWSER for /f "delims=" %%I in ('where chromium-gost.exe 2^>nul') do (
    if not defined BROWSER set "BROWSER=%%I"
)

if not defined BROWSER call :probe_dir "!LOCALAPPDATA!\Chromium\Application"
if not defined BROWSER call :probe_dir "!ProgramFiles!\Chromium\Application"
if not defined BROWSER call :probe_dir "!ProgramFiles(x86)!\Chromium\Application"
if not defined BROWSER call :probe_dir "!ProgramW6432!\Chromium\Application"
if not defined BROWSER call :probe_dir "!LOCALAPPDATA!\Chromium-Gost\Application"
if not defined BROWSER call :probe_dir "!ProgramFiles!\Chromium-Gost"
if not defined BROWSER call :probe_dir "!ProgramFiles!\Chromium-Gost\Application"
if not defined BROWSER call :probe_dir "!ProgramFiles(x86)!\Chromium-Gost"
if not defined BROWSER call :probe_dir "!ProgramFiles(x86)!\Chromium-Gost\Application"

if not defined BROWSER (
    echo Chromium-Gost не найден.
    echo Установите браузер или задайте переменную CHROMIUM_GOST с полным путём к .exe
    exit /b 1
)

for %%I in ("!BROWSER!") do set "CHROMIUM_DIR=%%~dpI"
set "PROFILE=!CHROMIUM_DIR!eaisto-gost-%RANDOM%-%RANDOM%"
mkdir "%PROFILE%" 2>nul
if errorlevel 1 (
    echo Не удалось создать папку профиля рядом с браузером: "%PROFILE%"
    echo Если Chromium установлен в Program Files, запустите макрос от имени администратора.
    exit /b 1
)

start "" /wait "!BROWSER!" ^
    --user-data-dir="%PROFILE%" ^
    --no-first-run ^
    --no-default-browser-check ^
    "%URL%"

set "TRIES=5"
:clean
rmdir /s /q "%PROFILE%" 2>nul
if exist "%PROFILE%" (
    set /a TRIES-=1
    if !TRIES! gtr 0 (
        ping -n 2 127.0.0.1 >nul
        goto clean
    )
    echo Внимание: не удалось полностью удалить "%PROFILE%" — закройте связанные процессы и удалите вручную.
    exit /b 1
)

endlocal
exit /b 0

:probe_dir
if defined BROWSER exit /b 0
if "%~1"=="" exit /b 0
if not exist "%~1\" exit /b 0
if exist "%~1\chromium-gost.exe" set "BROWSER=%~1\chromium-gost.exe" & exit /b 0
if exist "%~1\chrome.exe" set "BROWSER=%~1\chrome.exe" & exit /b 0
if exist "%~1\chromium.exe" set "BROWSER=%~1\chromium.exe" & exit /b 0
exit /b 0